MAXScript Extensions > MAXScript Extensions for Particle Flow > Particle View Access and MAXScript > Particle View Access >

# Particle_View : Helper

    Particle_View - superclass: helper super-superclass:node - classID: #(1962490631, 515064576)

Value > MAXWrapper > Node > Helper > Particle_View

| Particle Flow - Quick Navigation

Description:

Instances of this internal class are created by Particle Flow and returned bythe particleFlow.OpenParticleView() method. They represent the Particle View user interface. See particleFlow Global Interface for details.

Constructor:

    Not creatable by MAXScript

Properties:

    <Particle_View>.origin Point3

Get/Set the origin of the Particle View in screen pixel coordinates relatively to the upper left corner of the desktop.

    <Particle_View>.width Integer

Get/Set the width of the Particle View in pixels

    <Particle_View>.height Integer

Get/Set the height of the Particle View in pixels

    <Particle_View>.divider Point3

Get/Set the location of the divider of the Particle View.

    <Particle_View>.selected Node Array

Get/Set the array of selected nodes in the Particle View.

    <Particle_View>.Show_Parameters Boolean default:true

Controls the visibility of the Parameters panel at the right side of Particle View.

    <Particle_View>.Show_Action_Depot Boolean default:true

Controls the visibility of the Action Depot at the bottom of Particle View.

    <Particle_View>.Show_Action_Description Boolean default:true

Controls the visibility of the Action Description in the bottom right corner of Particle View.

    <Particle_View>.show_Particle_Count Integer default: 0

When set to 1, shows the Particle Count. Controls the checked state of the Particle View>Options>Track Update>Particle Count menu item.

    <Particle_View>.show_Action_Update Integer default: 0

When set to 1, shows the Action Update. Controls the checked state of the Particle View>Options>Track Update>Update Progress menu item.

    <Particle_View>.use_Dynamic_Names Integer default: 1

When set to 1, Particle View uses Dynamic names. Controls the checked state of the Particle View>Options>Use Dynamic Names menu item.

EXAMPLES AND RESULTS:
    --Open a Particle View
    pv = particleFlow.openParticleView()
    $Particle_View:Particle View 01 @ [0.000000,0.000000,0.000000]

    pv.name--since it is a helper, it has all node properties
    "Particle View 01"

    pv.Origin
    [9,77,0]
    pv.Origin = [100,0,0]
    [100,0,0]
    pv.Origin = [0,0,0]
    [0,0,0]

    --Get the current size of the Particle View
    pv.Width
    549
    pv.Height
    852
    --Set the size of the Particle View to 800 x 600
    pv.Width = 800
    800
    pv.Height = 600
    600

    pv.Divider
    [1,261,0]
    --Move the divider down to set Depot height to 100 pixels
    pv.Divider = [1,100,0]
    [1,100,0]

    pv.Show_Particle_Count
    0
    pv.Show_Particle_Count = 1
    1

    pv.Show_Action_Update
    0
    pv.Show_Action_Update = 1
    1

    pv.Use_Dynamic_Names
    1
    pv.Use_Dynamic_Names = 0
    0

The following MacroScript will open the Particle View on the right half of the desktop. If you are using a Dual Monitor setup with a single desktop on both monitors, this will open Particle View on the right monitor!

SCRIPT:
    macroScriptPView_TwoMonitors
    category: "Particle View"
    buttontext: "PView Half"
    tooltip: "Open Particle View on Right Half of Desktop"
    (
    -- open Particle View, get the Particle View object
    pv =ParticleFlow.openParticleView()

    -- get desktop size
    winsize = getMaxWindowSize()

    -- set Origin of PView to half desktop width and 0 height
    pv.origin = [winsize.x/2, 0,0]
    -- set Width to half desktop width
    pv.width = winsize.x/2
    -- set Height to full desktop height
    pv.height = winsize.y
    )

#### See Also

- particleFlow Global Interface

- Particle View Access