MAXScript Extensions > MAXScript Extensions for Particle Flow > Particle Flow Interfaces > Interfaces >

# Interface: initialEvents

Methods:

    <integer>getNumInitialActionLists()

Returns the number of initial Action Lists.

    <node>getInitialActionList <index>index

Returns the indexed Action List node.

    <bool>appendInitialActionList <node>actionList

Appends the specified Action List node, returns true on success.

    <bool>insertInitialActionList <node>actionList <index>index

Inserts the specified Action List node at the specified indexed position, returns true on success.

    <bool>removeInitialActionList <index>index

Removes the indexed Action List, returns true on success.

    <bool>hasInitialActionList <node>actionList <&index>index

    index is In and Out parameter

Returns true if the specified Action List node exists. In that case returns the index of the node in the index variable passed by reference.

EXAMPLE
    --Open Particle View to watch the results
    particleFlow.OpenParticleView()
    --> $Particle_View:Particle View 01 @ [0.000000,0.000000,0.000000]
    --Create a new Particle Flow Source
    pfs = PF_Source()
    --> $PF_Source:PF Source 01 @ [0.000000,0.000000,0.000000]
    --Get the number of Events connected to the PF_Source -
    --there are none so far
    pfs.getNumInitialActionLists()
    --> 0
    --Create a new empty event
    new_event = Event()
    --> $Event:Event 01 @ [0.000000,0.000000,0.000000]
    --Connect the new Event to the PF_Source by appending it to
    --the list of Initial Action Lists.
    --In result, a binding appears
    pfs.appendInitialActionList new_event
    --> true
    --Check again the number of Events connected to the PF_Source
    --As expected, there is one now
    pfs.getNumInitialActionLists()
    --> 1
    --Get the one Event connected to PF_Source -
    --it is the Event_01 we created
    pfs.getInitialActionList 1
    --> $Event:Event 01 @ [0.000000,0.000000,0.000000]
    --Now let’s create a second Event
    another_event = Event()
    --> $Event:Event 02 @ [0.000000,0.000000,0.000000]
    --This time we will not append to the list, but will insert the
    --new Event to the first position of the list
    pfs.insertInitialActionList another_event 1
    --> true
    --Checking again the number of connected Events,
    --we see that there are two already
    pfs.getNumInitialActionLists()
    --> 2
    --Let’s see the result of the Insertion - the first indexed Event
    --on the list is the second event we created...
    pfs.getInitialActionList 1
    --> $Event:Event 02 @ [0.000000,0.000000,0.000000]
    --...while the first Event we created is now at indexed position 2
    pfs.getInitialActionList 2
    --> $Event:Event 01 @ [0.000000,0.000000,0.000000]
    --We can remove the first Event and thus disconnect it
    -- from the PF_Source
    pfs.removeInitialActionList 1
    --> true
    --Checking the number of Events, there is only one connected now,
    --the second event is still in Particle View, but the binding is not
    --displayed anymore.
    pfs.getNumInitialActionLists()
    --> 1
    --Let’s see which Events are on the list and which are not.
    --We will need a variable to pass by reference to get the results
    ind = 0
    --> 0
    --Calling this method with the first Event we created and the
    --variable passed by reference returns true which means the event
    --is actually on the list
    pfs.hasInitialActionList new_event &ind
    --> true
    --Checking the content of the variable shows the index 1
    --of the Event on the list of connections
    ind
    --> 1
    --On the other hand, the second Event we removed before
    --does not appear on the list - the method returns false.
    pfs.hasInitialActionList another_event &ind
    --> false

This Interface is available in:

PF_Source : GeometryClass

#### See Also

- Particle Flow Interfaces