MAXScript Language Reference > 3ds Max Objects > Interfaces > Core Interfaces > Core Interfaces Documentation > I,J,K >

# Interface: IsolatedVertices

Interfaces > Core Interfaces > IsolatedVertices xView Checker

| Viewport Shading - Quick Navigation | Core Interfaces - Quick Navigation

The IsolatedVertices Core Interface exposes methods for interacting with the Isolated Vertices xView Checker.

Available in 3ds Max 2010 and higher.

Properties:

Does not expose any properties.

Methods:

    <enum>IsolatedVertices.Check <time>time <node>nodeToCheck <&index array>results

    Check enums: { #Failed | #Vertices | #Edges | #Faces}
    results is In and Out parameter

Performs an Isolated Vertices xView check at the given time on the specified node and returns its results in the array passed by-reference as third argument.

The method itself always returns the #vertex enum because the Isolated Vertices check only checks vertices and the values written to the results array always represent indices of isolated vertices.

    <bool>IsolatedVertices.hasPropertyDlg()

Returns true if the xView checker implements a property dialog, false if it does not.

In the particular case of the Isolated Vertices checker, it always returns false.

    <void>IsolatedVertices.showPropertyDlg()

Shows the property dialog of the xView checker, if implemented.

In the particular case of the Isolated Vertices checker this method does nothing.

EXAMPLE:
The following code creates a plane with 10x10 segments, then collapses it to editable mesh and deletes the first 20 faces, or a whole row of quads, leaving the outer vertices isolated.
    thePlane = plane width:100 length:100 widthsegs:10 lengthsegs:10
    --> $Plane:Plane01 @ [0.000000,0.000000,0.000000]
    convertToMesh thePlane
    --> $Editable_Mesh:Plane01 @ [0.000000,0.000000,0.000000]
    meshop.deleteFaces thePlane #{1..20} delIsoVerts:false
    --> OK
The following call to the IsolatedVertices.check() method will return the isolated vertices. It does NOT require the Isolated Vertices Checker to be active in the viewport and can be used in MAXScript code to acquire isolated vertex indices into an array:
    theResults = #() --we need an array to store the results in
    --> #()

    --We call the method by passing the time to check at,
    --the object to check and the by-reference array to store
    --the results in. The return result of the method itself
    --will be #vertex because the method operates on vertices
    --and the content of theResults array should be threated
    --as vertex indices:
    resultType = IsolatedVertices.Check currentTime thePlane &theResults
    --> #vertex

    --If we would print out the content of the array variable,
    --it will contain the indices of the isolated vertices:
    theResults
    --> #(1, 2, 3, 4, 5, 6, 7, 8, 9, 10, 11)

#### See Also

- xView Geometry Checker Access