## CreateSymmetryMap

### Introduced

v2.0

### Description

Creates a ClusterProperty that is a symmetry map along the YZ plane, the XZ plane or the XY plane. After you create a symmetry map, every time you move points on one side, the corresponding points on the other side of the symmetry map also move.

### Scripting Syntax

    oReturn = CreateSymmetryMap( PresetObj, [InputObj], [Name], [PropPresetObj] );

### Return Value

Returns a collection of symmetry maps.

### Parameters

Parameter | Type | Description
--- | --- | ---
PresetObj | String or a preset object (for example, an object obtained from SIGetPreset) | SymmetryMap operator preset Default Value: "SymmetryMap"
Possible Values: | Description:
SymmetryMap | Symmetry map
InputObj | String | List of clusters or objects or points clusters Default Value: Current selection
Name | String | Name of the symmetry map property Default Value: "Symmetry Map"
PropPresetObj | Preset object | Symmetry Map Property preset Default Value: "Symmetry Map Property" preset

### Examples

#### VBScript Example

    '

    ' This example sets up a symmetry map on a sphere and then moves some

    ' points on one side only with their corresponding points on the other

    ' side moving symmetrically.

    NewScene

    ' Create a sphere to apply the symmetry map to

    Set oSphere = CreatePrim( "Sphere", "NurbsSurface", "MySphere" )

    ' Create a symmetry map on the sphere (note how we do not need to specify the

    ' preset name of "SymmetryMap" for the first argument, since it is the default)

    Set oMaps = CreateSymmetryMap( , oSphere, "MySymmetryMap" )

    ' Log the name of the returned maps.  Here only one.

    LogMessage "Created Map: " & oMaps(0)

    ' Output information of running this script

    'INFO : sphere.polymsh.cls.SymmetryMapCls.MySymmetryMap

    ' Move some control points on one side only.

    Translate oSphere & ".pnt[(0,7)]", -1.90216784318022, 0, 0, _

    			siRelative, siViewSym, siObj, siXYZ

    Translate oSphere & ".pnt[(0,3)]", -4.39465725765814, 0, 0, _

    			siRelative, siViewSym, siObj, siXYZ

    Translate oSphere & ".pnt[(0,4)]", -1.60751873190734, 0, 0, _

    			siRelative, siViewSym, siObj, siXYZ

    Translate oSphere & ".pnt[(0,8)]", -0.714956303285471, 0, 0, _

    			siRelative, siViewSym, siObj, siXYZ

    Translate oSphere & ".pnt[(7,5)]", -0.570702900944422, 0, 0, _

    			siRelative, siViewSym, siObj, siXYZ

    ' Make the symmetry map visible in the camera view.

    ' This is equivalent to setting the "Property Maps" visibility option.

    ' Symmetrical areas map red->blue.

    ' Self symmetrical areas are green.

    SetValue "Camera.camvis.objctrlpropmaps", true

    SetDisplayMode "Camera", "constant"

### See Also

AddProp ClusterProperty