Parameter.Show

Controls whether the parameter is inspectable or not. Calling this method with false is identical to setting the siNotInspectable capability flag (see Parameter.SetCapabilityFlag). A parameter on a CustomProperty or an FXTree node that is non-inspectable will not be shown in the Property Page or in the Scene Explorer; however, it is still accessible to scripting (see ProjectItem.Parameters). By creating hidden parameters on a CustomProperty or custom Operator, a plug-in can save private state information inside a scene.

An alternative way to exclude a parameter from a Property Page is to not include it in the PPGLayout.

VBScript Example

'

' This example demonstrates how to create hidden parameters 

'

NewScene , false 

' -------------------------------------

'	Method 1: Using the Show method 

dim oPset1, oParam 

set oPset1 = Application.ActiveSceneRoot.AddProperty( "CustomProperty", false, "HiddenWithShow" ) 

set oParam = oPset1.AddParameter2( "Hidden", siDouble ) 

oParam.Show( false ) 

oPset1.AddParameter2 "NotHidden", siDouble  

InspectObj oPset1 , , , siLock

' -------------------------------------

'	Method 2: Create a Property Page layout excluding this parameter 

dim oPset2, oLayout 

set oPset2 = Application.ActiveSceneRoot.AddProperty( "CustomProperty", false, "HiddenWithLayout" ) 

oPset2.AddParameter2 "Hidden", siDouble  

oPset2.AddParameter2 "NotHidden", siDouble  

set oLayout = oPSet2.PPGLayout 

oLayout.Clear 

oLayout.AddItem "NotHidden" 

InspectObj oPset2 , , , siLock

' In either case you can still read and write the 

' the values from the Object Model 

Application.LogMessage "Old Value for " & oPset1.FullName & ": " & oPset1.Parameters("Hidden").Value

oPset1.Parameters("Hidden").Value = 5

Application.LogMessage "New Value for " & oPset1.FullName & ": " & oPset1.Parameters("Hidden").Value

Application.LogMessage "Old Value for " & oPset2.FullName & ": " & oPset2.Parameters("Hidden").Value

oPset2.Parameters("Hidden").Value = 25

Application.LogMessage "New Value for " & oPset2.FullName & ": " & oPset2.Parameters("Hidden").Value

' Output of above script:

'INFO : Old Value for HiddenWithShow: 0

'INFO : New Value for HiddenWithShow: 5

'INFO : Old Value for HiddenWithLayout: 0

'INFO : New Value for HiddenWithLayout: 25

Parameter.Show

Introduced

Description

C# Syntax

Scripting Syntax

Return Value

Examples

VBScript Example

See Also