Move2DShape

Introduced

3.0

Description

Moves the position of a shape and its pin. This is the scripting equivalent of selecting the Select Shapes tool in the ColorCorrect property page shape, and then clicking and dragging a shape around the Fx Viewer.

Note: To move the center, or pin, of the shape, use the Move2DShapePin command instead.

Scripting Syntax

    Move2DShape( [Shape], x, y )

Parameters

Parameter | Type | Description
Shape | String | Parameter path name for the shape you are moving. Default Value: Current selection. Note: If the current selection is not a valid shape, an error occurs.
x | Double | Specifies the new position of the point in X.
y | Double | Specifies the new position of the point in Y.

Examples

VBScript Example

    '
    ' This example demonstrates how to set a garbage matte mask for a
    ' ColorCorrect operator in the FxTree and then move it to the top
    ' right corner of the Fx Viewer.
    '
    ' Create a new FxTree
    set oTree = CreateFxTree()

    ' Get the projects path for the current system
    sPath = InstallationPath( siProjectPath )
    set oClip = CreateImageClip( sPath & "\Pictures\noIcon.pic", "NewClip" )

    ' Use the clip to create a new image clip operator
    set oOperator = AddImageClipFxOp( oTree, oClip )

    ' Add a Color Correct operator to the same tree
    set oCCOp = AddFxOp( oTree, "Color Correct" )

    ' Connect the two operators
    ConnectFxOp oOperator, oCCOp, "1"

    ' Since the ConnectFxOp command does not return the new operator,
    ' you need to get it from the OperatorCollection on the FxTree object
    for each oMember in oTree.FxOperators
       if oMember.Name = "ColorCorrect" then
           set oGBMatteOp = oMember
           exit for
       end if
    next

    ' Adjust the HSV Offset and Gain levels so you can see the
    ' results of the color correction
    SetValue oGBMatteOp.FullName & ".MasterHueShift," _
           & oGBMatteOp.FullName & ".MasterOffset," _
           & oGBMatteOp.FullName & ".MasterGain", _
           Array(0, 0.820731514055631, 0.852844886888196)

    ' Add the 2D shape (mask shape) to the GarbageMatte and reshape it so you can see
    ' the shape when you open the Fx Viewer with the ColorCorrect operator selected
    set oRotospline = Add2DShape( oGBMatteOp & ".GarbageShapes", "Bezier" )
    Move2DShapePin oRotospline, 124.333333333333, 145.166666666667

    aPointPositions = Array(56, 207, 196, 170, 179, 85, 132, 142, 108, 105, 75, 162)
    Add2DShapePointArray oRotospline, aPointPositions

    ' Move the image to the top right corner of the Fx Viewer
    Move2DShape oRotospline, 56, 44

See Also

Add2DShape | Scale2DShape | Move2DShapePin | Set2DShapeRotation

Autodesk Softimage v7.5