CreateCompound

Introduced

1.0

Description

Creates a compound clip (as a ClipContainer object) from a set of Clip objects.

Scripting Syntax

    CreateCompound( Model, [InputObj], [Compound], [Track], [Time], [Name] )

Parameters

Parameter | Type | Description
Model | String | The model to which to add the new compound clip.
InputObj | String | List of clips to put in the compound clip. Default Value: Current selection
Compound | String | The compound container (track owner) to which to add the new compound clip. If left empty, the command tries to find the right place to nest the new compound.
Track | String | The track to which to add the new compound clip. If left empty, a new track will be created to hold the new clip.
Time | Double | Frame at which to add the compound. Default Value: Current frame.
Name | String | The name to use for the new clip.

Return Value

Returns the compound clip as a ClipContainer object.

Examples

VBScript Example

    '
    ' This example sets up two action clips for a sphere (one on the
    ' X-position and one on the Y-position), stores the actions, and
    ' then creates a compound clip using those stored clips.
    '
    ' Set up the scene
    Set oRoot = ActiveSceneRoot
    Set oSphere = CreatePrim( "Sphere", "NurbsSurface", "MySphere" )

    ' Setting key frames on XPos and YPos at various frames
    SaveKey oSphere.posx, 1, -9.0
    SaveKey oSphere.posx, 10, 3.0
    SaveKey oSphere.posx, 30,-3.0
    SaveKey oSphere.posx, 40, 9.0
    SaveKey oSphere.posy, 1, -2.0
    SaveKey oSphere.posy, 30, 2.0

    ' Store fcurve into source Actions
    Set oAct1 = StoreAction( oSphere, oSphere.posx, 2, _
       "PlotXPosAction", True, 1, 40, True, False )

    Set oAct2 = StoreAction( oSphere, oSphere.posy, 2, _
       "PlotYPosAction", True, 1, 30, True, False )

    ' Add an action clip with the 2 source action in tracks
    Set oClip1 = AddClip( oRoot, oAct1, , , 1 )
    Set oClip2 = AddClip( oRoot, oAct2, , , 1 )

    ' Create a new compound action clip using the two action clips
    CreateCompound oRoot, oClip1 & "," & oClip2, "Mixer", , 0, "Compound Clip"

Autodesk Softimage v7.5